Сделай так:
.model tiny
.code
org 100h
start:
mov ax, cs
mov ds, ax
mov ah, 9
mov dx, offset var_2
int 21h
mov ax, 4c00h
int 21h
; Variables
var_1 dq 981731987897491838
var_2 db 'KS-09-1', '$'
var_3 dw 126000q
var_4 dt 9def8ae34df5a1e2d37h
var_5 dw 277q
end startСобирай так:
tasm.exe /la lab1.asm
tlink.exe /t lab1.objПолучишь LAB1.COM (не ЕХЕ!). И не спрашивай меня почему. Если нужен принципиально EXE - могу и его сделать.
PS Покури вложение, DOS Fn 09h.
Добавлено позже:
Если точно следовать условию задания, то нужно сделать так:
.model tiny
.code
org 100h
start: mov ax, cs ; Зададим DS
mov ds, ax
; Выведем var_1, dq - 8 байт
mov bx, offset var_1
mov cx,8
OutVar1: mov al, ds:[bx]
call hex_al
inc bx
dec cx
jnz OutVar1
call linefeed
; Выведем var_2, это строка
mov ah, 9
mov dx, offset var_2
int 21h
call linefeed
; Выведем var_3, dw - 2 байта слово
mov bx, offset var_3
mov ax, ds:[bx]
call hex_ax
call linefeed
; Выведем var_4, dt - 10 байт
mov bx, offset var_4
mov cx,10
OutVar4: mov al, ds:[bx]
call hex_al
inc bx
dec cx
jnz OutVar4
call linefeed
; Выведем var_5, dw - 2 байта слово
mov bx, offset var_5
mov ax, ds:[bx]
call hex_ax
; Выход в DOS
mov ax, 4c00h
int 21h
; Разные процедурки
; Переводит строку
linefeed proc near
push ax
mov al,0Dh
int 29h
mov al,0Ah
int 29h
pop ax
ret
linefeed endp
;Вывод HEX из ax
hex_ax proc near
push ax
mov al,ah
call hex_al
pop ax
call hex_al
ret
hex_ax endp
;Вывод HEX из al
hex_al proc near
push ax
mov ah,al
shr al,4h
and al,0Fh
cmp al,0Ah
sbb al,69h
das
int 29h
mov al,ah
and al,0Fh
cmp al,0Ah
sbb al,69h
das
int 29h
pop ax
ret
hex_al endp
; Variables
var_1 dq 981731987897491838
var_2 db 'KS-09-1', '$'
var_3 dw 126000q
var_4 dt 9def8ae34df5a1e2d37h
var_5 dw 277q
end startСобирать все так же:
tasm.exe /la lab1.asm
tlink.exe /t lab1.objА вывод будет таким:
F:\WORK\ASSM>LAB1.COM
7EA144A30AD09F0D
KS-09-1
AC00
372D1E5ADF34AEF8DE09
00BF
F:\WORK\ASSM>
PS Лови Зубкова, афигительная книжка по асму. Жаль, что в электронной версии не хватает целого раздела по программированию железа (в бумаге он есть).
